<%
Option Explicit
Dim Request_Data
 
Class SimpleUpload
 
Private int_ClassName
Private int_Version
Private int_LastUpdate
Private int_Author
Private int_Homepage
Public dic_Form,dic_File
 
Private int_FileLen
 
Private Sub Class_Initialize() 
	Dim m_strError,Crlf,Data_Start,Data_End
	m_strError = "" 
	int_ClassName = "SimpleUpload"
	int_Version = "0.1"
	int_LastUpdate = "2009-05-17"
	int_Author = "coco"
	int_Homepage = "http://www.ioio.name/"
	Crlf = chrB(13) & chrB(10)
 
	Set dic_Form=Server.CreateObject("Scripting.Dictionary")
	Set dic_File=Server.CreateObject("Scripting.Dictionary")
	If Request.TotalBytes < 1 Then Exit Sub
	Request_Data = Request.BinaryRead(Request.TotalBytes)	
	Data_Start = 1
	Data_End = LenB(Request_Data)
	Dim pos_InStrB,sStart,iStart,iInfoEnd,sInfo,iFindStart,iFindEnd,sFormName,sFormValue,sFileName
	pos_InStrB = InStrB(Data_Start,Request_Data,Crlf)
	sStart = MidB(Request_Data,1, pos_InStrB-1)
	iStart = LenB(sStart)	
	Data_Start = Data_Start + iStart + 1
	while (Data_Start + iStart) < Data_End
		iInfoEnd = InStrB(Data_Start,Request_Data,Crlf & Crlf)
		sInfo = BinaryToString(MidB(Request_Data,Data_Start,iInfoEnd-Data_Start))
		Data_Start = InStrB(iInfoEnd,Request_Data,sStart)
		iFindStart = InStr(22,sInfo,"name=""",1)+6
		iFindEnd = InStr(iFindStart,sInfo,"""",1)
		sFormName = lcase(Mid(sinfo,iFindStart,iFindEnd-iFindStart))
		If InStr (45,sInfo,"filename=""",1) > 0 Then
			iFindStart = InStr(iFindEnd,sInfo,"filename=""",1)+10
			iFindEnd = InStr(iFindStart,sInfo,"""",1)
			sFileName = Mid (sinfo,iFindStart,iFindEnd-iFindStart)
			Dim theFile
			Set theFile = new FileInfo
			theFile.FileName = getFileName(sFileName)
			theFile.FilePath = getFilePath(sFileName)
			theFile.FileStart = iInfoEnd+3
			theFile.FileSize = Data_Start - iInfoEnd-6
			theFile.FormName= sFormName
			if not dic_File.Exists(sFormName) then
		  		dic_File.add sFormName,theFile
			end if	
		Else
			sFormValue = BinaryToString(MidB(Request_Data,iInfoEnd+4,Data_Start - iInfoEnd-4))
			if dic_Form.Exists(sFormName) then
				dic_Form(sFormName)=dic_Form(sFormName)&", "&sFormValue
			else
				dic_Form.Add sFormName,sFormValue
			end if
		End If
		Data_Start = Data_Start + iStart + 1
	wend
End Sub 
 
Private Sub Class_Terminate() 
	m_strError = "" 
	int_Version = ""
	Set dic_Form=Nothing
	Set dic_File=Nothing
End Sub 
 
Public Property Get ClassName 
	ClassName = int_ClassName
End Property
 
Public Property Get Version 
	Version = int_Version
End Property
 
Public Property Get LastUpdate 
	LastUpdate = int_LastUpdate
End Property
 
Public Property Get Author 
	Author = int_Author 
End Property
 
Public Property Get Homepage 
	Homepage = int_Homepage 
End Property
 
Public Property Get FileLen 
	FileLen = int_FileLen
End Property
 
Public Function PrintInfo() 
	Response.Write("Class Name: "+ClassName()+"<br/>") 
	Response.Write("Version: "+Version()+"<br/>")
	Response.Write("LastUpdate: "+LastUpdate()+"<br/>") 
	Response.Write("Author: "+Author()+"<br/>")
	Response.Write("Homepage: "+Homepage()+"<br/>")
End Function 
 
Function BinaryToString(Binary)
  Dim I, S
  For I = 1 To LenB(Binary)
    S = S & Chr(AscB(MidB(Binary, I, 1)))
  Next
  BinaryToString = S
End Function
 Private function GetFilePath(FullPath)
  If FullPath <> "" Then
   GetFilePath = left(FullPath,InStrRev(FullPath, "\"))
  Else
   GetFilePath = ""
  End If
 End  function
 
Private function GetFileName(FullPath)
  If FullPath <> "" Then
   GetFileName = mid(FullPath,InStrRev(FullPath, "\")+1)
  Else
   GetFileName = ""
  End If
End  function
 
Public function Form(strForm)
   strForm=lcase(strForm)
   if not dic_Form.exists(strForm) then
     Form=""
   else
     Form=dic_Form(strForm)
   end if
end function
 
Public function File(strFile)
   strFile=lcase(strFile)
   if not dic_File.exists(strFile) then
     set File=new FileInfo
   else
     set File=dic_File(strFile)
   end if
End function
End Class
 
Class FileInfo
  dim FormName,FileName,FilePath,FileSize,FileType,FileStart
  Private Sub Class_Initialize 
    FileName = ""
    FilePath = ""
    FileSize = 0
    FileStart= 0
    FormName = ""
    FileType = ""
  End Sub
 
Public Function GetBinary
	Dim tStream,bb
	set bb=CreateObject("Adodb.Stream")
    bb.Type=1
    bb.Open
	bb.Write Request_Data
	bb.position=FileStart
 
	Set tStream = Server.CreateObject("ADODB.Stream")
	tStream.Type = 1
	tStream.Open
 
	bb.copyto tStream,FileSize
	bb.Close
	tStream.Position=0
	GetBinary = tStream.Read
	tStream.Close
	set bb=nothing
	set tStream=nothing
End Function
 
Public function SaveAs(FullPath)
    dim dr,ErrorChar,i,bb
    SaveAs=true
    if trim(fullpath)="" or FileStart=0 or FileName="" or right(fullpath,1)="/" then exit function
    set dr=CreateObject("Adodb.Stream")
	set bb=CreateObject("Adodb.Stream")
	bb.Mode=3
    bb.Type=1
    bb.Open
	bb.Write Request_Data
 
	dr.Mode=3
    dr.Type=1
    dr.Open
 
	bb.position=FileStart
	bb.copyto dr,FileSize
	bb.Close
    dr.SaveToFile FullPath,2
    dr.Close
	set bb=nothing
    set dr=nothing 
    SaveAs=false
  end function
End Class
%>

<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<!--#include file="simpleupload.asp"-->
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
<title>aaa</title>
</head>
 
<body>
<%
Dim conn,connstr,accessdb,rs
accessdb="images.mdb"
Set conn=Server.CreateObject("ADODB.Connection")
connstr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(accessdb)
 
Dim upload,filet,filename
Set upload=new simpleupload
 
if upload.Form("sub")<>"submit" then
Response.Write("添加成功")
set filet=upload.file("img") 
conn.Open connstr
Set Rs = Server.CreateObject("ADODB.Recordset")
Rs.Open  "Select * from file where id=0",conn,1,3
	'If Rs.BOF or Rs.EOF Then
	Rs.AddNew
	Rs("upload_date")=Now()
	Rs("title")=Trim(upload.Form("title"))
	Rs("content")=Trim(upload.Form("con"))
	Rs("pdf").appendchunk filet.GetBinary
	Rs.update
	'End If
	Rs.Close
	Set Rs=Nothing
conn.Close
Response.Write("添加成功")
Response.Write(upload.Form("abc"))
end if
%>
<form action="" method="post" enctype="multipart/form-data">
<input name="title" type="text" value="" /><br />
<textarea name="con" cols="" rows=""></textarea>
<br />
<input name="img" type="file" />
<input name="sub" type="submit" value="submit" />
</form>
 
</body>
</html>